Re: QUEUE "folyatás"

Sziasztok !

Mivel  Huszar Zoltan maganlevelben kerte a programomat megkerestem.
(Kiderult, hogy megvan csak nem az Alpha, hanem VAX gepen van.
Azert nem talaltam elsore. :-) )

Mivel, lehet, hogy mast is erdekel a listara kuldom a programot, amit a
$ Help Lexicals f$getqui
tanulanyozasa utan nagyon egyszeru atirni ahhoz, hogy esetleg
szelektiven torolje azt, amit szeretnel.
(A csupa nagybetuvel irt kodreszek valoszinuleg onnan erednek, mert
en nagyon keves nagybetut hasznalok a DCL-ben is.)

$ set noverify
$ sh time
$INDUL:
$ van = 0
$  TEMP = F$GETQUI("")
$  QLOOP:
$  QNAME = F$GETQUI("DISPLAY_QUEUE","QUEUE_NAME","*")
$  IF QNAME .EQS. "" THEN goto WAIT
$!  if f$locate("PS32",qname) .lt. f$length(qname)
$!   then
$!      WRITE SYS$OUTPUT ""
$!      w f$locate("PS32",qname)
$!      WRITE SYS$OUTPUT "QUEUE: ", QNAME
$!   else
$!    goto QLOOP
$!   endif
$  JLOOP:
$  NOACCESS = F$GETQUI("DISPLAY_JOB","JOB_INACCESSIBLE",,"ALL_JOBS")
$  IF NOACCESS .EQS. "TRUE" THEN GOTO JLOOP
$  IF NOACCESS .EQS. "" THEN GOTO QLOOP
$  entry = F$GETQUI("DISPLAY_JOB","ENTRY_NUMBER",,"FREEZE_CONTEXT")
$  prio = F$GETQUI("DISPLAY_JOB","PRIORITY",,"FREEZE_CONTEXT")
$ if prio .gt. 189
$  then
$    newprio = prio - 150
$    on error then cont
$    set entry/prio='newprio' 'entry'
$    set noon
$  user = F$GETQUI("DISPLAY_JOB","USERNAME",,"FREEZE_CONTEXT")
$  jobname = F$GETQUI("DISPLAY_JOB","JOB_NAME",,"FREEZE_CONTEXT")
$    write sys$output "''qname'    ''user'    ''jobname'    ''entry'    
''prio'"
$    van = van +1
$  else
$  endif
$  GOTO JLOOP
$WAIT:
$ if van .gt. 0
$   then
$    sh time
$   else
$  endif
$ wait 0:5:0
$ goto INDUL

Eddig a program es most az, amivel elinditottam.
$  RUN SYS$SYSTEM:LOGINOUT.EXE/DETACH -
         /OUTPUT=sys$manager:SET_ENTRY.log -
         /input=sys$manager:SET_ENTRY.com -
         /noaccount -
         /PROCESS_NAME=Set_Entry -
         /AST_LIMIT=10 -
         /BUFFER_LIMIT=2000 -
         /EXTENT=1000 -
         /FILE_LIMIT=10 -
         /IO_BUFFERED=40 -
         /IO_DIRECT=20 -
         /QUEUE_LIMIT=10 -
         /ENQUEUE_LIMIT=100 -
         /MAXIMUM_WORKING_SET=1024 -
         /PAGE_FILE=6000 -
         /PRIORITY=4 -
         /PRIVILEGES=(SYSPRV,oper) -
         /UIC=[1,4] -
         /NORESOURCE
$

Udv. Tibi